/*

     :copyright: 2011 by Florian Boesch <pyalot@gmail.com>.

     :license: GNU AGPL3, see LICENSE for more details.

 */

 vertex:

     attribute vec3 position, normal;

     attribute vec2 texcoord;

     varying vec2 v_texcoord;

     varying vec3 v_normal;

     uniform mat4 proj, view;

     uniform mat3 view_rot;

     void main(void) {

         gl_Position = proj * view * vec4(position, 1.0);

         v_texcoord = texcoord;

         v_normal = normal;

     }

 fragment:

     uniform vec2 viewport;

     uniform mat4 inv_proj;

     uniform mat3 inv_view_rot;

     uniform float shading_mix, reflectivity;

     varying vec2 v_texcoord;

     varying vec3 v_normal;

     uniform samplerCube diffuse, specular;

     vec3 get_world_normal(){

         vec2 frag_coord = gl_FragCoord.xy/viewport;

         frag_coord = (frag_coord-0.5)*2.0;

         vec4 device_normal = vec4(frag_coord, 0.0, 1.0);

         vec3 eye_normal = normalize((inv_proj * device_normal).xyz);

         vec3 world_normal = normalize(inv_view_rot*eye_normal);

         return world_normal;

     }

     void main(void){

         vec3 eye_normal = get_world_normal();

         vec3 normal = normalize(v_normal);

         vec3 specular_normal = reflect(eye_normal, normal);

         float reflection = smoothstep(0.0, 1.0, pow(dot(-eye_normal, normal), reflectivity));

         vec4 specular_color = textureCube(specular, specular_normal) * reflection;

         vec4 diffuse_color = textureCube(diffuse, normal);

         vec4 result = mix(specular_color, diffuse_color, shading_mix);

         gl_FragColor = vec4(pow(result.rgb, vec3(1.0/2.2)), 1.0);

     }